class Pair {
  float x,y;
  Pair (float x, float y) {
    this.x = x;
    this.y = y;
  }
}

float zoom = 1;
ArrayList pairs = new ArrayList();
String dataLines[];

int currentIdx = 0;
int drawCount = 100;
int screenX = 500;
int screenY = 300;

float xtrans = 0;
float ytrans = 0;
float startX = 0;
float startY = 0;


void setup() {
  dataLines = loadStrings("lentes.txt");

  for (int i=0; i<dataLines.length; i++) {
    //0          1     2      3     4     5       6     7      8
    //IDPACIENTE FECHA MEDICO RLEOD RLCOD RLCODGR RLEOI RLCOI RLCOIGR 
    String line[] = dataLines[i].split(":"); 
    pairs.add(new Pair(Float.parseFloat(line[3]), Float.parseFloat(line[4])));
  }
  size(screenX,screenY);
  framerate(30);
  background(255);

  PFont font = loadFont("Monaco-10.vlw");
  textFont(font,10);

  //noLoop();
}


void draw() {
  // x esferico
  // y cilindrico
  for (int i=currentIdx; (i<pairs.size() && i<currentIdx+drawCount); i++) {
    Pair p = (Pair)pairs.get(i);
    float x = p.x;
    float y = p.y;

    x = (x+random(-0.1,0.1))*zoom + screenX/2;
    y = (-y+random(-0.1,0.1))*zoom + screenY/2;

    x = x+xtrans;
    y = y+ytrans;

    if (p.x == 0 || p.y ==0) 
      stroke(0,0,0,5);
    else if (p.x > 0) 
      stroke(205,205,0,5);
    else 
      stroke(255,0,0,5);

    strokeWeight(4);
    strokeCap(ROUND);
    point(x,y);
  }
  currentIdx = currentIdx+drawCount;

  // pintar coordenadas
  stroke(255,255);
  fill(255,255);
  rect(0,0,100,20);
  fill(0,255);
  float px = float(round(100*(mouseX-screenX/2)/zoom))/100;
  float py = -1 * float(round(100*(mouseY-screenY/2)/zoom))/100;
  text(px+":"+py, 5,10);  

}

void mousePressed() {
  startX = mouseX;
  startY = mouseY;
}

void mouseDragged() {
  xtrans = xtrans + mouseX - startX ;
  ytrans = ytrans + mouseY - startY  ;
  startX = mouseX;
  startY = mouseY;
  currentIdx = 0;
  background(255);
  redraw();
}

void keyPressed() {
  if (key == 'z') {
    zoom = zoom * 2;
  } 
  else if (key == 'x') {
    zoom = zoom/2;
  }
  currentIdx = 0;
  background(255);
  redraw();
}